Kbase P44034: How to parent different types of frames to each other?
| Autor |
Progress Software Corporation - Progress |
| Acesso |
Público |
| Publicação |
9/26/2003 |
|
Status: Unverified
GOAL:
How to parent different types of frames to each other?
FIX:
Kindly note that the word "parent" is herein used loosely since the FRAME can not directly parent another frame:
1. To make a static frame the parent of another static frame:
DEFINE VARIABLE h1 AS HANDLE NO-UNDO.
DEFINE VARIABLE h2 AS HANDLE NO-UNDO.
DEFINE FRAME StaticFrame1
WITH COL 1 ROW 1
SIZE 20 BY 20
TITLE "Static1".
DEFINE FRAME StaticFrame2
WITH COL 2 ROW 2
SIZE 15 BY 15
TITLE "Static2".
ASSIGN
h1 = FRAME StaticFrame1:HANDLE
h2 = FRAME StaticFrame2:HANDLE
h2:FRAME = h1.
VIEW FRAME StaticFrame1.
PAUSE 3.
HIDE FRAME StaticFrame2.
PAUSE 3.
HIDE FRAME StaticFrame1.
PAUSE 3.
VIEW FRAME StaticFrame2.
PAUSE 3.
HIDE FRAME StaticFrame1.
2. To make a static frame the parent of a dynamic frame:
DEFINE VARIABLE DynFrame AS HANDLE NO-UNDO.
DEFINE FRAME StaticFrame
WITH COL 1 ROW 1
SIZE 20 BY 20
TITLE "Static1".
CREATE FRAME DynFrame
ASSIGN
WIDTH-CHARS = 15
HEIGHT-CHARS = 15
ROW = 2
COL = 2
FRAME = FRAME StaticFrame:HANDLE
TITLE = "DynFrame".
VIEW DynFrame.
PAUSE 3.
HIDE DynFrame.
PAUSE 3.
VIEW DynFrame.
PAUSE 3.
HIDE FRAME StaticFrame.
3. To make a dynamic frame the parent of another dynamic frame:
DEFINE VARIABLE DynFrame1 AS WIDGET-HANDLE.
DEFINE VARIABLE DynFrame2 AS WIDGET-HANDLE.
CREATE FRAME DynFrame1
ASSIGN
WIDTH-CHARS = 20
HEIGHT-CHARS = 20
ROW = 1
COL = 1
TITLE = "frame1".
CREATE FRAME DynFrame2
ASSIGN
WIDTH-CHARS = 10
HEIGHT-CHARS = 10
ROW = 5
COL = 5
FRAME = DynFrame1
TITLE = "frame2".
VIEW DynFrame1.
PAUSE 3.
VIEW DynFrame2.
PAUSE 3.
HIDE DynFrame1.
4. To make a dynamic frame the parent of a static frame:
DEFINE VARIABLE DynFrame AS WIDGET-HANDLE.
DEFINE VARIABLE h AS HANDLE NO-UNDO.
CREATE FRAME DynFrame
ASSIGN
WIDTH-CHARS = 20
HEIGHT-CHARS = 20
ROW = 1
COL = 1
TITLE = "DynFrame".
DEFINE FRAME StaticFrame
WITH COL 1 ROW 1
SIZE 10 BY 10
TITLE "Static".
ASSIGN
h = FRAME StaticFrame:HANDLE
h:FRAME = DynFrame.
VIEW DynFrame.
PAUSE 3.
HIDE FRAME StaticFrame.
PAUSE 3.
HIDE DynFrame.
PAUSE 3.
VIEW FRAME StaticFrame.